package {
 
	import Box2DAS.Common.V2;
	import Box2DAS.Dynamics.StepEvent;
 
	import shapes.Box;
 
	import flash.events.Event;
 
	/**
	 * @author Aymeric
	 */
 
	public class Momie extends Box {
 
		private var _arriere:Boolean;
 
		public function Momie() {
 
			this.addEventListener(Event.ADDED_TO_STAGE, _init);
		}
 
		private function _init(evt:Event):void {
 
			this.removeEventListener(Event.ADDED_TO_STAGE, _init);
		}
 
		public override function create():void {
			reportBeginContact = true;
			reportEndContact = true;
			super.create();
 
			listenWhileVisible(world, StepEvent.STEP, _parseInput);
		}
 
		private function _parseInput(evt:Event):void {
 
			if (_arriere == false) {
				if (this.x < 800) {
					b2body.ApplyImpulse(new V2(0.2, 0), b2body.GetWorldCenter());
				} else {
					_arriere = true;
					this.gotoAndPlay("marche_gauche");
				}
			} else {
 
				if (this.x > 30) {
					b2body.ApplyImpulse(new V2(-0.2, 0), b2body.GetWorldCenter());
 
				} else {
					_arriere = false;
					this.gotoAndPlay("marche_droite");
				}
			}
 
		}
	}
}

package {
 
	import Box2DAS.Collision.*;
	import Box2DAS.Common.*;
	import Box2DAS.Dynamics.*;
 
	import misc.*;
 
	import shapes.*;
 
	import wck.*;
 
	import flash.events.*;
	import flash.utils.Timer;
 
	/**
	 * @author Aymeric
	 */
 
	public class Heros extends Box {
 
		public var contacts:ContactList;
 
		private var _momie:Momie;
		private var _memoireSens:String;
		private var _timer:Timer;
 
		public function Heros() {
 
			this.addEventListener(Event.ADDED_TO_STAGE, _init);
		}
 
		private function _init(evt:Event):void {
 
			this.removeEventListener(Event.ADDED_TO_STAGE, _init);
		}
 
		public override function create():void {
 
			reportBeginContact = true;
			reportEndContact = true;
			// fixedRotation = true;
			super.create();
			listenWhileVisible(world, StepEvent.STEP, parseInput, false, 10);
			listenWhileVisible(this, ContactEvent.BEGIN_CONTACT, handleContact);
			contacts = new ContactList();
			contacts.listenTo(this);
		}
 
		public function handleContact(ctcEvt:ContactEvent):void {
 
			_momie = ctcEvt.other.m_userData as Momie;
			var piece:Circle = ctcEvt.other.m_userData as Circle;
			if (_momie) {
				// Util.addChildAtPosOf(world, new Boum(), p);
 
				_momie.gotoAndStop("mort");
				_momie.removeAllListeners();
 
				_timer = new Timer(500, 1);
				_timer.addEventListener(TimerEvent.TIMER_COMPLETE, _supprimerMomie);
				_timer.start();
			}
 
			if (piece) {
				piece.remove();
				piece = null;
			}
		}
 
		private function _supprimerMomie(tEvt:TimerEvent):void {
 
			_momie.remove();
			_momie = null;
 
			_timer.removeEventListener(TimerEvent.TIMER_COMPLETE, _supprimerMomie);
			_timer = null;
		}
 
		public function parseInput(e:Event):void {
			var manifold:b2WorldManifold = null;
			var dot:Number = -1;
			if (!contacts.isEmpty()) {
				contacts.forEach(function(keys:Array, c:ContactEvent) {
					var wm:b2WorldManifold = c.getWorldManifold();
					if (wm.normal) {
						var d:Number = wm.normal.dot(gravity);
						if (!manifold || d > dot) {
							manifold = wm;
							dot = d;
						}
					}
				});
				contacts.clean();
			}
			var left:Boolean = Input.kd('A', 'LEFT');
			var right:Boolean = Input.kd('D', 'RIGHT');
			var jump:Boolean = Input.kp(' ', 'UP');
			var v:V2;
 
			if (jump && manifold) {
 
				v = manifold.normal.clone().multiplyN(-7);
				b2body.ApplyImpulse(v, b2body.GetWorldCenter());
 
			} else if (left) {
 
				if (this.currentLabel != "marche_gauche") {
					this.gotoAndPlay("marche_gauche");
				}
				b2body.ApplyImpulse(new V2(-0.2, 0), b2body.GetWorldCenter());
				_memoireSens = "gauche";
 
			} else if (right) {
 
				if (this.currentLabel != "marche_droite") {
					this.gotoAndPlay("marche_droite");
				}
				b2body.ApplyImpulse(new V2(0.2, 0), b2body.GetWorldCenter());
				_memoireSens = "droite";
 
			} else {
				if (_memoireSens == "gauche") {
					this.gotoAndPlay("init_gauche");
				} else {
					this.gotoAndPlay("init_droite");
				}
 
			}
		}
	}
}